0
点赞
收藏
分享

微信扫一扫

Unity中URP下实现水体(水面反射)

独西楼Q 02-28 21:30 阅读 3

文章目录


前言

在上篇文章中,我们实现了水体的高光反射效果。

  • Unity中URP下实现水体(水面高光)

在这篇文章中,我们来实现水体的反射效果。


一、原理

以下两个方法,对反射纹理采样时,都是使用顶点的反射向量进行采样的。

1、法一:使用立方体纹理 CubeMap,作为反射纹理使用

  • Unity中Shader立方体纹理Cubemap

2、法二:使用反射探针生成环境反射图,所谓反射的采样纹理

  • Unity中Shader反射环境

二、实现水面反射

1、定义和申明CubeMap

  • 在属性面板定义一个 Cube 传入反射纹理
  • 在Pass中,申明纹理和采样器(注意:反射纹理为 TEXTURECUBE 类型)
  • 我使用的CubeMap如下

在这里插入图片描述

2、反射向量需要什么

3、计算 N ⃗ \vec{N} N

得到世界空间下的 法线坐标 和 法线纹理 线性过渡的效果

  • 在顶点着色器中,转化得到世界空间下的法线坐标
  • 在属性面板传入,需要使用的法线纹理
  • 定义、申明控制过渡的值
  • 得到线性过渡的法线信息

4、计算 V ⃗ \vec{V} V

5、计算反射向量 R ⃗ \vec{R} R

6、对CubeMap进行纹理采样

注意:

  1. 使用的采样方式为SAMPLE_TEXTURECUBE
  2. 采样UV为:反射向量

请添加图片描述

7、模拟出菲涅尔效果(近处反射弱,远处反射强)

在这里插入图片描述

  • fresnel = 1 - dot(N,V)
  • 用 fresmel 和 reflectionTex 相乘得出拟真的反射效果

请添加图片描述

8、环境反射效果 与 高光反射效果 相乘,得到只有在高光处反射环境的效果

请添加图片描述

9、用该效果与上篇文章的结果相加得出最终效果

请添加图片描述
请添加图片描述


三、最终代码

//水的深度
Shader "MyShader/URP/P4_8"
{
    Properties 
    {
        [Header(Base)]
        _WaterColor1("WaterColor1",Color) = (1,1,1,1)
        _WaterColor2("WaterColor2",Color) = (1,1,1,1)
        
        [PowerSlider(3)]_WaterSpeed("WaterSpeed",Range(0,1)) = 0.1
        
        [Header(Foam)]
        _FoamTex("FoamTex",2D) = "white"{} 
        _FoamColor("FoamColor",Color) = (1,1,1,1)
        _FoamRange("FoamRange",Range(0,5)) = 1
        _FoamNoise("FoamNoise",Range(0,3)) = 1
        
        [Header(Distort)]
        _NormalTex("NormalTex",2D) = "white"{}
        [PowerSlider(3)]_Distort("Distort",Range(0,0.3)) = 0
        
        [Header(Specular)]
        _SpecularColor("Specular Color",Color) = (1,1,1,1)
        [PowerSlider(3)]_SpecularIntensity("Specular Intensity",Range(0,1)) = 0.6
        _Smoothness("Smoothness",Range(0,10)) = 10
        
        [Header(Reflection)]
        _ReflectionTex("ReflectionTex",Cube) = "white"{}
        [PowerSlider(3)]_NormalIntensity("NormalIntensity",Range(0,1)) = 0.5
        
    }
    
    SubShader
    {
        Tags
        {
            //告诉引擎,该Shader只用于 URP 渲染管线
            "RenderPipeline"="UniversalPipeline"
            //渲染类型
            "RenderType"="Transparent"
            //渲染队列
            "Queue"="Transparent"
        }
        //Blend SrcAlpha OneMinusSrcAlpha
        ZWrite Off
        Pass
        {
          
            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // Pragmas
            #pragma target 2.0
            
            // Includes
            #include "Packages/com.unity.render-pipelines.core/ShaderLibrary/Color.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Input.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

            CBUFFER_START(UnityPerMaterial)
            half4 _WaterColor1;
            half4 _WaterColor2;
            
            half _WaterSpeed;
            
            half4 _FoamColor;
            half _FoamRange;
            half _FoamNoise;
            half4 _FoamTex_ST;

            half _Distort;
            half4 _NormalTex_ST;

            half4 _SpecularColor;
            half _SpecularIntensity;
            half _Smoothness;

            half _NormalIntensity;
            CBUFFER_END

            
            TEXTURE2D(_CameraDepthTexture);SAMPLER(sampler_CameraDepthTexture);
            TEXTURE2D(_FoamTex);SAMPLER(sampler_FoamTex);
            TEXTURE2D(_CameraOpaqueTexture);SAMPLER(sampler_CameraOpaqueTexture);
            TEXTURE2D(_NormalTex);SAMPLER(sampler_NormalTex);
            TEXTURECUBE(_ReflectionTex);SAMPLER(sampler_ReflectionTex);
            //struct appdata
            //顶点着色器的输入
            struct Attributes
            {
                float3 positionOS : POSITION;
                float2 uv : TEXCOORD0;
                half3 normalOS : NORMAL;
            };
            //struct v2f
            //片元着色器的输入
            struct Varyings
            {
                float4 positionCS : SV_POSITION;
                float2 uv : TEXCOORD0;//foamUV
                float4 screenPos : TEXCOORD1;
                float3 positionVS : TEXCOORD2;
                float3 positionWS : TEXCOORD3;
                float3 normalWS : TEXCOORD4;
                float4 normalUV : TEXCOORD5;
            };
            //v2f vert(Attributes v)
            //顶点着色器
            Varyings vert(Attributes v)
            {
                Varyings o = (Varyings)0;
                o.positionWS = TransformObjectToWorld(v.positionOS);
                o.positionVS = TransformWorldToView(o.positionWS);
                o.positionCS = TransformWViewToHClip(o.positionVS);
                
                o.screenPos = ComputeScreenPos(o.positionCS);
                //计算得到泡沫纹理采样需要的顶点世界空间下的坐标值的流动效果
                o.uv += o.positionWS.xz *_FoamTex_ST.xy + _Time.y * _WaterSpeed;
                //计算得到水下扭曲纹理的流动UV
                o.normalUV.xy = TRANSFORM_TEX(v.uv,_NormalTex) + _Time.y * _WaterSpeed;
                o.normalUV.zw = TRANSFORM_TEX(v.uv,_NormalTex) + _Time.y * _WaterSpeed * half2(-1.1,1.3);
                o.normalWS = TransformObjectToWorldNormal(v.normalOS);
                
                return o;
            }
            //fixed4 frag(v2f i) : SV_TARGET
            //片元着色器
            half4 frag(Varyings i) : SV_TARGET
            {
                //1、水的深度
                //获取屏幕空间下的 UV 坐标
                float2 screenUV = i.positionCS.xy / _ScreenParams.xy;
                half depthTex = SAMPLE_TEXTURE2D(_CameraDepthTexture,sampler_CameraDepthTexture,screenUV).x;
                //深度图转化到观察空间下
                float depthScene = LinearEyeDepth(depthTex,_ZBufferParams);
                //获取水面模型顶点在观察空间下的Z值(可以在顶点着色器中,对其直接进行转化得到顶点观察空间下的坐标)
                float4 depthWater = depthScene + i.positionVS.z;
                
                //2、水的颜色,线性插值得到水 和 接触物体的水的 颜色的过度
                half4 waterColor = lerp(_WaterColor1,_WaterColor2,depthWater);
                
                //3、水面泡沫
                //对泡沫纹理进行采样(这里使用顶点世界空间下的坐标进行纹理采样,防止水体缩放影响泡沫的平铺和重复方式)
                half4 foamTex = SAMPLE_TEXTURE2D(_FoamTex,sampler_FoamTex,i.uv.xy);
                
                foamTex = pow(abs(foamTex),_FoamNoise);
                
                //这里增加一个调整深度图范围的功能
                half4 foamRange = depthWater * _FoamRange;
                
                //使用泡沫纹理 和 泡沫范围 比较得到泡沫遮罩
                half4 foamMask = step(foamRange,foamTex);
                
                //给泡沫加上颜色
                half4 foamColor = foamMask * _FoamColor;
                
                //4、水下的扭曲
                half4 normalTex1 = SAMPLE_TEXTURE2D(_NormalTex,sampler_NormalTex,i.normalUV.xy);
                half4 normalTex2 = SAMPLE_TEXTURE2D(_NormalTex,sampler_NormalTex,i.normalUV.zw);
                half4 normalTex = normalTex1 * normalTex2;
                float2 distortUV = lerp(screenUV,normalTex.xy,_Distort);
                half4 cameraOpaqueTex = SAMPLE_TEXTURE2D(_CameraOpaqueTexture,sampler_CameraOpaqueTexture,distortUV);
                
                //5、水的高光
                //Specular = SpecularColor * Ks * pow(max(0,dot(N,H)), Shininess)
                Light light = GetMainLight();
                half3 L = light.direction;
                half3 V = normalize(_WorldSpaceCameraPos.xyz - i.positionWS.xyz);
                //修改法线实现,波光粼粼的效果
                half4 N = lerp(half4(i.normalWS,1),normalize(normalTex),_NormalIntensity);
                
                half3 H = normalize(L + V);
                half4 specular = _SpecularColor * _SpecularIntensity * pow(max(0,dot(N.xyz,H)),_Smoothness);
                
                //水的反射
                half3 reflectionUV = reflect(-V,N.xyz);
                half4 reflectionTex = SAMPLE_TEXTURECUBE(_ReflectionTex,sampler_ReflectionTex,reflectionUV);
                
                half fresnel = 1 - saturate(dot(i.normalWS,V));
                half4 reflection = reflectionTex * fresnel;
                
                //水的焦散


                half4 col = (foamColor + waterColor) * cameraOpaqueTex + (specular * reflection);
                
                return col;
            }
            ENDHLSL
        }
    }
    FallBack "Hidden/Shader Graph/FallbackError"
}
举报

相关推荐

0 条评论