Built-in转URP Chapter10(1)-反射

话不多说，直接上代码，具体区别我后边会补充上，

暂时委屈各位，先锻炼下自己的“找不同”的能力，哈哈：

Built-CG写法：

Shader "Unity Shaders Book/Chapter 10/Reflection" {
	Properties {
		_Color("Color Tint", Color) = (1,1,1,1)
		_ReflectColor("Reflect Color", Color) = (1,1,1,1)
		_ReflectAmount("Reflect Amount", Range(0, 1)) = 1
		_Cubemap("Cube Map", Cube) = "_Skybox" {}
	}

	SubShader {
		Tags {"Queue"="Geometry" "RenderType"="Opaque"}
		Pass {
			Tags {"LightMode"="ForwardBase"}
			CGPROGRAM
			#include "Lighting.cginc"
			#include "AutoLight.cginc"

			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fwdbase

			fixed4 _Color;
			fixed4 _ReflectColor;
			fixed _ReflectAmount;
			samplerCUBE _Cubemap;

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldPos : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				fixed3 worldViewDir : TEXCOORD2;
				fixed3 worldRefl : TEXCOORD3;
				SHADOW_COORDS(4)
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
				o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
				TRANSFER_SHADOW(o);
				return o;
			}

			fixed4 frag(v2f i) :SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 viewDir = normalize(i.worldViewDir);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 diffuse = _LightColor0.rgb * _Color.rgb * saturate(dot(worldNormal, lightDir));
				fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten;
				return fixed4(color, 1.0);

				// fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;
				// fixed3 albedo = reflection.rgb * _Color.rgb;
				// fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				// fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(worldNormal, lightDir));
				// UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				// return fixed4(ambient + diffuse * atten, 1.0);
			}

			ENDCG
		}
	}

	FallBack "Reflective/VertexLit"
}

URP+HLSL写法：

Shader "Unity Shaders Book/Chapter 10/Reflection" {
	Properties {
		_Color("Color Tint", Color) = (1,1,1,1)
		_ReflectColor("Reflect Color", Color) = (1,1,1,1)
		_ReflectAmount("Reflect Amount", Range(0, 1)) = 1
		_Cubemap("Cube Map", Cube) = "_Skybox" {}
	}

	SubShader {
		Tags {
			"RenderPipeline"="UniversalPipeline"
			"Queue"="Geometry" "RenderType"="Opaque"
		}
		Pass {
			Tags {"LightMode"="UniversalForward"}

			HLSLPROGRAM
			#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
			#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

			#pragma vertex vert
			#pragma fragment frag

			// #pragma multi_compile_fwdbase

CBUFFER_START(UnityPerMaterial)
			half4 _Color;
			half4 _ReflectColor;
			half _ReflectAmount;
CBUFFER_END

			TEXTURECUBE(_Cubemap);
			SAMPLER(sampler_Cubemap);

			// samplerCUBE _Cubemap;

			struct a2v {
				float4 vertex : POSITION;
				half3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				half3 worldPos : TEXCOORD0;
				half3 worldNormal : TEXCOORD1;
				half3 worldViewDir : TEXCOORD2;
				half3 worldRefl : TEXCOORD3;
				// SHADOW_COORDS(4)
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = TransformObjectToHClip(v.vertex.xyz);
				o.worldPos = mul(UNITY_MATRIX_M, v.vertex).xyz;
				o.worldNormal = TransformObjectToWorldNormal(v.normal);
				o.worldViewDir = _WorldSpaceCameraPos - o.worldPos;
				// worldViewDir是从顶点->相机, -worldViewDir是从相机->顶点
				// 可以这样理解，从相机指向顶点，reflect就可以计算出，从顶点向外的反射方向
				o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
				// TRANSFER_SHADOW(o);
				return o;
			}

			half4 frag(v2f i): SV_Target {
				half3 worldNormal = normalize(i.worldNormal);
				// half3 viewDir = normalize(i.worldViewDir);
				// fixed3 lightDir = normalize(_MainLightPosition.xyz);

				// 主光源
				float4 shadowCoord = TransformWorldToShadowCoord(i.worldPos);
				Light mainLight = GetMainLight(shadowCoord);
				half3 lightDir = normalize(mainLight.direction);

				half3 ambient = half3(unity_SHAr.w, unity_SHAg.w, unity_SHAb.w);;
				half3 diffuse = mainLight.color.rgb * _Color.rgb * saturate(dot(worldNormal, lightDir));
				half3 reflection = SAMPLE_TEXTURECUBE(_Cubemap, sampler_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;
				// UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				half3 color = ambient + lerp(diffuse, reflection, _ReflectAmount);
				return half4(color, 1.0);

				return half4(1,1,1,1);
			}

			ENDHLSL
		}
	}

	// FallBack "Reflective/VertexLit"
	// 不知道URP用什么fallback代替
	FallBack "Universal Render Pipeline/Simple Lit"
}