0
点赞
收藏
分享

微信扫一扫

word vba 操作表格, 设置表格中的段落

林塬 2022-12-29 阅读 183

一、表格中的段落设置

Sub 表格中的段落设置()
  Dim p As Paragraph
  For Each p In ActiveDocument.Paragraphs
    If p.Range.Information(wdWithInTable) Then '针对表格内的段落
      With p.Range.ParagraphFormat
        .Alignment = wdAlignParagraphLeft '对齐方式
        .OutlineLevel = wdOutlineLevelBodyText '大纲级别
        .CharacterUnitLeftIndent = 0 '左缩进
        .CharacterUnitRightIndent = 0 '右缩进
        .CharacterUnitFirstLineIndent = 2 '首行缩进
        .LineUnitBefore = 0 '段前间距
        .LineUnitAfter = 0 '段后间距
        .LineSpacingRule = wdLineSpace1pt5 '行距
        
        .WidowControl = True '孤行控制
        .KeepWithNext = False '与下段同页
        .KeepTogether = False '段中不分页
        .PageBreakBefore = False '段前分页
        
        .FarEastLineBreakControl = True '按中文习惯控制首尾字符
        .WordWrap = False '允许西文在单词中间换行
        .HangingPunctuation = True '允许标点溢出边界
  
        .HalfWidthPunctuationOnTopOfLine = False '允许行首标点压缩
        .AddSpaceBetweenFarEastAndAlpha = True '自动调整中文与西文的间距
        .AddSpaceBetweenFarEastAndDigit = True '自动调整中文与数字的间距
      End With
    End If
  Next
End Sub

二、段落设置的难点注释

注释:
'首行缩进
'用正值设置首行缩进,用负值设置悬挂缩进
'首行缩进:是每段的第一行向后移,其他所有行不变
'悬挂缩进:是每段除第一行不变以外,其他所有行向后移

'孤行控制
'Word中“孤行”通常分为“段首孤行”和“段未孤行”,是指在页面顶端的段落末行或者页面底端的段落首行,那单独的一行即被称为孤行
'在较长的Word文档中,一段的第一行出现在上一页的页尾,或是一段的最后一行出现在下一页的页首。
'特别是有时候孤行仅有一两个字,单独出现在页面上显示十分扎眼和容易产生阅读误解。

'与下段同页
'需要同时勾选 孤行控制 才会起作用
'如果指定段落与它的下一段位于同一页上,则该属性值为 True

'段中不分页
'指定段落中的所有行都位于同一页上,则该属性值为 True

'按中文习惯控制首尾字符 
'如果一行只能写20个字,但是很不巧你第21个字是一个标点符号,例如“,”。如果
'你不选择这个选项的话,这个“,”就会出现在下一行的开头,而这样的写法是不符合'中文的习惯的。所以当你选了这个选项的话,这个“,”就会被安排在这一行的最后。

'允许标点溢出边界
'允许标点符号比段落中其他行的边界超出一个字符,为了防止标点出现在下一行的行
'头。如果不使用该选项,则所有的行和标点符号都必须严格对齐。不过这里的标点只
'限于半角英文标点。在页面设置--稿纸模式时使用在这里设置了,稿纸设置模块同时设'置,这个取消了稿纸设置模块同时取消。

'允许西文在单词中间换行
'比如说word这个单词,允许西文在单泀中间换行就是说可以wo在上一行,而rd在下一行,一般不勾选。

'允许行首标点压缩
'中文标点都是占一个汉字宽度的,允许压缩的话,标点宽度有可能会小于一个汉字宽度。

'自动调整中文与西文的间距
'自动调整中文与数字的间距
'按照习惯,中文与西文之间、中文与数字之间的间距应该比中文与中文之间的间距宽
'一点。要保持这个习惯,就需要勾选这两个选项。

举报

相关推荐

0 条评论