ABAP面向对象之工厂模式（Factory Pattern）-CFANZ编程社区

概述

工厂模式（Factory Pattern）是 Java 中最常用的设计模式之一。这种类型的设计模式属于创建型模式，它提供了一种创建对象的最佳方式。在工厂模式中，我们在创建对象时不会对客户端暴露创建逻辑，并且是通过使用一个共同的接口来指向新创建的对象。

介绍

定义一个创建对象的接口，让其子类自己决定实例化哪一个工厂类，工厂模式使其创建过程延迟到子类进行。

解决的问题

主要解决接口选择的问题。

何时使用：

我们明确地计划不同条件下创建不同实例时

如何解决：

让其子类实现工厂接口，返回的也是一个抽象的产品。

应用实例：

您需要一辆汽车，可以直接从工厂里面提货，而不用去管这辆汽车是怎么做出来的，以及这个汽车里面的具体实现。
Hibernate 换数据库只需换方言和驱动就可以。

优点：

一个调用者想创建一个对象，只要知道其名称就可以了。
扩展性高，如果想增加一个产品，只要扩展一个工厂类就可以。
屏蔽产品的具体实现，调用者只关心产品的接口。

缺点：

每次增加一个产品时，都需要增加一个具体类和对象实现工厂，使得系统中类的个数成倍增加，在一定程度上增加了系统的复杂度，同时也增加了系统具体类的依赖。这并不是什么好事。

使用场景：

日志记录器：记录可能记录到本地硬盘、系统事件、远程服务器等，用户可以选择记录日志到什么地方。
数据库访问，当用户不知道最后系统采用哪一类数据库，以及数据库可能有变化时。
设计一个连接服务器的框架，需要三个协议，“POP3”、“IMAP”、“HTTP”，可以把这三个作为产品类，共同实现一个接口。

实现

我们将创建一个 Shape 接口和实现 Shape 接口的实体类。下一步是定义工厂类 ShapeFactory。

FactoryPatternDemo，我们的演示类使用 ShapeFactory 来获取 Shape 对象。它将向 ShapeFactory 传递信息（CIRCLE / RECTANGLE / SQUARE），以便获取它所需对象的类型。

创建接口

INTERFACE  if_shape .
  METHODS draw.
ENDINTERFACE.

实现接口的实体类

矩形

CLASS cl_rectangle DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.

CLASS cl_rectangle IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_rectangle->draw() method.'.
  ENDMETHOD.
ENDCLASS.

方形

CLASS cl_square  DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.

CLASS cl_square IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_square->draw() method.'.
  ENDMETHOD.
ENDCLASS.

圆形

CLASS cl_circle  DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.

CLASS cl_circle IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_circle->draw() method.'.
  ENDMETHOD.
ENDCLASS.

创建工厂类，，返回基于给定信息的实体类的对象。

CLASS cl_shape_factory  DEFINITION.
  PUBLIC SECTION.
    METHODS:  get_shape
      IMPORTING
                iv_shape_type      TYPE string
      RETURNING VALUE(ro_instance) TYPE REF TO if_shape.

ENDCLASS.

CLASS cl_shape_factory IMPLEMENTATION.
  METHOD get_shape .
    CASE to_upper( iv_shape_type ).
      WHEN 'CIRCLE'.
        ro_instance = NEW cl_circle( ).
      WHEN 'RECTANGLE'.
        ro_instance = NEW cl_rectangle( ).
      WHEN  'SQUARE'.
        ro_instance = NEW cl_square( ).
      WHEN OTHERS.
    ENDCASE.
  ENDMETHOD.
ENDCLASS.

使用该工厂，通过传递类型信息来获取实体类的对象。

CLASS cl_application DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS:  run .
ENDCLASS.


CLASS cl_application IMPLEMENTATION.
  METHOD run.

    DATA(lo_shape_factory) = NEW cl_shape_factory( ).

    "获取 Circle 的对象，并调用它的 draw 方法
    DATA(lo_shape1) = lo_shape_factory->get_shape( 'CIRCLE' ).

    " 调用 Circle 的 draw 方法
    lo_shape1->draw( ).

    "获取 Rectangle 的对象，并调用它的 draw 方法
    DATA(lo_shape2)  = lo_shape_factory->get_shape( 'RECTANGLE').

    "调用 Rectangle 的 draw 方法
    lo_shape2->draw( ).

    "获取 Square 的对象，并调用它的 draw 方法
    DATA(lo_shape3)  = lo_shape_factory->get_shape( 'SQUARE').

    "调用 Square 的 draw 方法
    lo_shape3->draw( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  cl_application=>run(  ).

实现的UML

SAP 生成UML

ABAP面向对象之工厂模式（Factory Pattern）_实体类

验证结果：