RationalDMS2023高级编程

DECL/CHAR,128,tit1,tit2,tit3,partid1
partid1=PROMPT/'工件号？'
tit1=ASSIGN/' 东风朝阳柴油机有限责任公司'
tit2=ASSIGN/CONCAT(' 工件号： ',partid1,'     操作者：郭作莲')
tit3=ASSIGN/CONCAT(' 日期: ',SDATE(),'    时间: ',STIME(),'     名称： 缸体      工序号：20')
$$'名称： 缸体 工序号：20'）
TEXT/OUTFIL,'===================================================================='
TEXT/OUTFIL,tit1
TEXT/OUTFIL,tit2
TEXT/OUTFIL,tit3
TEXT/OUTFIL,'===================================================================='
DISPLY/OFF

ENDFIL

SNSLCT/SA(P1_90_0P180_0)
TECOMP/MACH,ON
TECOMP/PART,ON,11.4,ALL
SNSET/APPRCH,3.0000
F(PLA_1)=FEAT/PLANE,CART,-492.6123,-404.8414,-530.2051,0.99999952,-0.00005951,0.00097574
MEAS/PLANE,F(PLA_1),3
ENDMES

DECL/DOUBLE,PLA_1_I,PLA_1_J,PLA_1_K
PLA_1_I=OBTAIN/FA(PLA_1),6
PLA_1_J=OBTAIN/FA(PLA_1),7
PLA_1_K=OBTAIN/FA(PLA_1),8
F(CIR_1)=FEAT/CIRCLE,INNER,CART,-499.6969,-655.9243,-613.5029,PLA_1_I,PLA_1_J,PLA_1_K,15.9991
MEAS/CIRCLE,F(CIR_1),3
ENDMES

F(CIR_2)=FEAT/CIRCLE,INNER,CART,-498.5497,-301.8350,-613.7332,PLA_1_I,PLA_1_J,PLA_1_K,16.0034
MEAS/CIRCLE,F(CIR_2),3
ENDMES

F(LIN_1)=FEAT/LINE,BND,CART,-499.6969,-655.9243,-613.5029,-498.5497,-301.8350,-613.7332,1.00000000,0.00000000,0.00000000
CONST/LINE,F(LIN_1),BF,FA(CIR_1),FA(CIR_2)

D(DAT_1) = DATSET/FA(PLA_1),XDIR,XORIG,FA(LIN_1),YDIR,FA(CIR_1),YORIG,ZORIG
SNSET/CLRSRF,FA(PLA_1),15.0000
MODE/PROG,MAN

F(PLA_2)=FEAT/PLANE,CART,-0.0055,175.4316,90.2076,1.00000000,-0.00001995,0.00008868
MEAS/PLANE,F(PLA_2),11
    PTMEAS/CART,0.0058,383.5850,-0.0532,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0018,417.1174,76.3785,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0012,410.6103,164.5790,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0067,295.2952,160.4332,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0059,246.4495,114.6579,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0016,197.7748,10.0973,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0149,57.9416,75.2396,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0207,61.8988,160.0783,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0127,-42.5937,152.5321,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,-0.0092,-58.0371,72.8277,0.99999952,0.00006015,-0.00097570
    PTMEAS/CART,0.0083,-40.2962,5.5360,0.99999952,0.00006015,-0.00097570
ENDMES

F(CIR_3)=FEAT/CIRCLE,INNER,CART,-5.0000,0.0000,0.0000,1,0,0,16.0000
MEAS/CIRCLE,F(CIR_3),6
ENDMES

F(CIR_4)=FEAT/CIRCLE,INNER,CART,-5.0000,354.0000,0.0000,1.00000000,0.00000000,0.00000000,16.0000
MEAS/CIRCLE,F(CIR_4),6
ENDMES

F(LIN_2)=FEAT/LINE,BND,CART,-5.0000,0.0000,0.0000,-5.0000,354.0000,0.0000,1.00000000,0.00000000,0.00000000
CONST/LINE,F(LIN_2),BF,FA(CIR_3),FA(CIR_4)

D(DAT_2) = DATSET/FA(PLA_2),XDIR,XORIG,FA(LIN_2),YDIR,FA(CIR_3),YORIG,ZORIG


DECL/REAL,X1,Y1,Z1,D1,ANG1
DECL/INTGR,I1,J1
DECL/CHAR,20,CYNAME

Z1=ASSIGN/83
SNSET/APPRCH,3.000
SNSET/RETRCT,2.000

DO/I1,0,3
$$------------------------进气
X1=ASSIGN/-44
D1=ASSIGN/14
Y1=ASSIGN/-24+118*I1
CYNAME=ASSIGN/CONCAT('CYL_',STR(I1+10))
F(@CYNAME)=FEAT/CYLNDR,INNER,CART,X1,Y1,Z1,1,0,0,D1
MEAS/CYLNDR,F(@CYNAME),8
DO/J1,0,3
X1=ASSIGN/-44
ANG1=ASSIGN/3.1415926/2*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,0,-COS(ANG1),-SIN(ANG1)
ENDDO

X1=ASSIGN/-76
DO/J1,0,3
ANG1=ASSIGN/3.1415926/2*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,0,-COS(ANG1),-SIN(ANG1)
ENDDO
ENDMES

X1=ASSIGN/-3
D1=ASSIGN/42.5
CYNAME=ASSIGN/CONCAT('CIR_',STR(I1+10))
F(@CYNAME)=FEAT/CIRCLE,INNER,CART,X1,Y1,Z1,1,0,0,D1
MEAS/CIRCLE,F(@CYNAME),8
DO/J1,0,7
ANG1=ASSIGN/3.1415926/4*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,COS(3.1415926/4),-COS(ANG1)*SIN(3.1415926/4),-SIN(ANG1)*SIN(3.1415926/4)
ENDDO
ENDMES

$$------------------------排气
X1=ASSIGN/-45
D1=ASSIGN/14
Y1=ASSIGN/28+118*I1
CYNAME=ASSIGN/CONCAT('CYL_',STR(I1+20))
F(@CYNAME)=FEAT/CYLNDR,INNER,CART,X1,Y1,Z1,1,0,0,D1
MEAS/CYLNDR,F(@CYNAME),8
DO/J1,0,3
X1=ASSIGN/-45
ANG1=ASSIGN/3.1415926/2*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,0,-COS(ANG1),-SIN(ANG1)
ENDDO

X1=ASSIGN/-76
DO/J1,0,3
ANG1=ASSIGN/3.1415926/2*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,0,-COS(ANG1),-SIN(ANG1)
ENDDO
ENDMES

X1=ASSIGN/-3
D1=ASSIGN/36.0
CYNAME=ASSIGN/CONCAT('CIR_',STR(I1+20))
F(@CYNAME)=FEAT/CIRCLE,INNER,CART,X1,Y1,Z1,1,0,0,D1
MEAS/CIRCLE,F(@CYNAME),8
DO/J1,0,7
ANG1=ASSIGN/3.1415926/4*J1
PTMEAS/CART,X1,Y1+COS(ANG1)*D1/2,Z1+SIN(ANG1)*D1/2,COS(3.1415926/4),-COS(ANG1)*SIN(3.1415926/4),-SIN(ANG1)*SIN(3.1415926/4)
ENDDO
ENDMES

ENDDO


DISPLY/TERM,V(TEXT)
DECL/CHAR,128,tit1,tit2,tit3,partid1
partid1=PROMPT/'工件号？'
tit1=ASSIGN/' 东风朝阳柴油机有限责任公司'
tit2=ASSIGN/CONCAT(' 工件号： ',partid1,'     操作者：郭作莲')
tit3=ASSIGN/CONCAT(' 日期: ',SDATE(),'    时间: ',STIME(),'     名称： 缸体      工序号：20')
$$'名称： 缸体 工序号：20'）
TEXT/OUTFIL,'===================================================================='
TEXT/OUTFIL,tit1
TEXT/OUTFIL,tit2
TEXT/OUTFIL,tit3
TEXT/OUTFIL,'===================================================================='

V(V1)= VFORM/ACT
V(V2)= VFORM/NOM,ACT,DEV
T(FLAT_1)=TOL/FLAT,0.0500

T(CORTOL_1)=TOL/CORTOL,YAXIS,-0.0500,0.0500
T(CORTOL_2)=TOL/CORTOL,ZAXIS,-0.0500,0.0500
T(DIAM_1)=TOL/DIAM,0.0000,0.0180

T(CORTOL_3)=TOL/CORTOL,YAXIS,-0.1000,0.1000
T(CORTOL_4)=TOL/CORTOL,ZAXIS,-0.1000,0.1000
T(DIAM_2)=TOL/DIAM,0.0000,0.0180
T(POS_1)=TOL/POS,2D,0.1000

DISPLY/TERM,V(v1)
OUTPUT/FA(PLA_2),TA(FLAT_1)
OUTPUT/FA(CIR_3),TA(CORTOL_1),TA(CORTOL_2),TA(DIAM_1)
OUTPUT/FA(CIR_4),TA(CORTOL_1),TA(CORTOL_2),TA(DIAM_1)

DISPLY/TERM,V(v2)
OUTPUT/FA(CYL_10),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_10),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_11),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_11),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_12),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_12),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_13),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_13),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)

OUTPUT/FA(CYL_20),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_20),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_21),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_21),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_22),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_22),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)
OUTPUT/FA(CYL_23),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2),TA(POS_1)
OUTPUT/FA(CIR_23),TA(CORTOL_3),TA(CORTOL_4),TA(DIAM_2)

DO/I1,0,3
CYNAME=ASSIGN/CONCAT('CYL_',STR(I1+10))
T(CRNOUT_1)=TOL/CRNOUT,0.0500,FA(@CYNAME)
CYNAME=ASSIGN/CONCAT('CIR_',STR(I1+10))
OUTPUT/FA(@CYNAME),TA(CRNOUT_1)

CYNAME=ASSIGN/CONCAT('CYL_',STR(I1+20))
T(CRNOUT_1)=TOL/CRNOUT,0.0500,FA(@CYNAME)
CYNAME=ASSIGN/CONCAT('CIR_',STR(I1+20))
OUTPUT/FA(@CYNAME),TA(CRNOUT_1)
ENDDO

 

ENDFIL