UNITS/MM, ANGDEC
WKPLAN/XYPLAN
PRCOMP/ON
TECOMP/OFF
FLY/2
MODE/PROG, MAN
SNSET/APPRCH, 10.000000
SNSET/RETRCT, 10.000000
SNSET/DEPTH, 0.000000
SNSET/SEARCH, 20.0000
SNSET/CLRSRF, 5.000000
RECALL/D(MCS)
SNSLCT/S(ROOTSN1)
GEOALG/CIRCLE, LSTSQR
GEOALG/ARC, LSTSQR
GEOALG/PLANE, LSTSQR
$$
$$
DECL/COMMON,DOUBLE,NOM_D
DECL/COMMON,DOUBLE,P_Cord[3],SPH_Cord[3]
TEMPSTRING = PROMPT/TITLE,'25球检验程序',TEXT,'请将测头移动到标准球的正上方',$
TEXT,'标准球的理论直径为',EDIT,NOM_D
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$取得标准球球心的坐标值$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$定义标准球理论值$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
F(S_Point) = FEAT/POINT,CART,0,0,0,0,0,1
MEAS/POINT,F(S_Point),0
ENDMES
P_Cord[1] = OBTAIN/FA(P_Point),3
P_Cord[2] = OBTAIN/FA(P_Point),4
P_Cord[3] = OBTAIN/FA(P_Point),5
MEAS/POINT,F(P_Point),1
PTMEAS/CART, P_cord[1], P_cord[2], P_cord[3]-1, 0, 0, 1
ENDMES
P_Cord[1] = OBTAIN/FA(P_Point),3
P_Cord[2] = OBTAIN/FA(P_Point),4
P_Cord[3] = OBTAIN/FA(P_Point),5
F(M_SPH) = FEAT/SPHERE, OUTER, CART, P_cord[1], P_cord[2], P_cord[3]-NOM_D/2,$
NOM_D
MODE/AUTO,PROG,MAN
MEAS/SPHERE,F(M_SPH),5
ENDMES
SPH_Cord[1] = OBTAIN/FA(M_SPH),4
SPH_Cord[2] = OBTAIN/FA(M_SPH),5
SPH_Cord[3] = OBTAIN/FA(M_SPH),6
F(M_SPH) = FEAT/SPHERE, OUTER, CART, SPH_Cord[1], SPH_Cord[2],$
SPH_Cord[3],NOM_D
MEAS/SPHERE,F(M_SPH),5
ENDMES
SPH_Cord[1] = OBTAIN/FA(M_SPH),4
SPH_Cord[2] = OBTAIN/FA(M_SPH),5
SPH_Cord[3] = OBTAIN/FA(M_SPH),6
F(M_SPH) = FEAT/SPHERE, OUTER, CART, SPH_Cord[1], SPH_Cord[2],$
SPH_Cord[3],NOM_D
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$$$$$$$$$$$$$$$$$$$$$$$$$$$平移坐标系$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
D(SPH25) = TRANS/XORIG,FA(M_SPH),YORIG,FA(M_SPH),ZORIG,FA(M_SPH)
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$产生测量点$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
SNSET/APPRCH, 5
SNSET/RETRCT, 5
SNSET/DEPTH, 0
SNSET/SEARCH, 5
SNSET/CLRSRF, 5
MODE/PROG,MAN
DECL/COMMON,DOUBLE,Radian_SPH
DECL/COMMON,INTGR,I,J,K
Radian_SPH = ASSIGN/22.5*3.141592654/180
MEAS/SPHERE,F(M_SPH),25
PTMEAS/CART, 0, 0, NOM_D/2, 0, 0, 1
DO/I,1,4
RECALL/D(SPH25)
D(TEMP_CRD) = TRANS/ZORIG, COS(I*Radian_SPH)*(NOM_D/2)
K = ASSIGN/MOD(I,2) + 1
DO/J,1,8,K
D(TEMP_CRD) = ROTATE/ZAXIS,45*(J-1)+22.5*I
PTMEAS/CART, SIN(I*Radian_SPH)*NOM_D/2, 0, 0, 1, 0, 0
ENDDO
ENDDO
ENDMES
