#山涧果子#
DECL/LOCAL, REAL, LPNUM,HEIGHT, TOLERROR
DECL/LOCAL, CHAR, 20, BARAXIS,PROB,ANS
DECL/COMMON,DOUBLE,DR_PRBRAD
DECL/COMMON, DOUBLE, VI, VJ, VK, VI2, VJ2, VK2, DCX, DCY, DCZ, DX, DY, DZ, BARDIR, DMAX, DMIN
DECL/COMMON, DOUBLE, GAGEHEIGHT, GAGEWIDTH, ENDCLEAR,STD
DECL/COMMON, DOUBLE, ZGAP[5], XGAP[5], BLENGTH[5], ZP, XP, BL
$$ do..loop<<<循环测量次数>>>为3,可以根据实际需要修改循环测量次数
LPNUM = ASSIGN/3
$$ HEIGHT抬高的<<<安全距离>>>为43，可以根据实际情况修改此数值
HEIGHT = ASSIGN/43
$$ XGAP表示<<<块规之间的端面距离>>>，请查看 GageBlock.JPG 图片里的图解
XGAP[1] = ASSIGN/0
XGAP[2] = ASSIGN/0
XGAP[3] = ASSIGN/0
XGAP[4] = ASSIGN/0
XGAP[5] = ASSIGN/48
$$ ZGAP表示<<<块规间距>>>，请查看 GageBlock.JPG 图片里的图解
ZGAP[1] = ASSIGN/0
ZGAP[2] = ASSIGN/ZGAP[1] + 19
ZGAP[3] = ASSIGN/ZGAP[1] + 38
ZGAP[4] = ASSIGN/ZGAP[1] + 57
ZGAP[5] = ASSIGN/ZGAP[1] + 76
$$ <<<块规的长度>>>，500，400，300，200，30，可以自行修改
BLENGTH[1] = ASSIGN/499.99975
BLENGTH[2] = ASSIGN/400.00028
BLENGTH[3] = ASSIGN/300.00030
BLENGTH[4] = ASSIGN/199.99943
BLENGTH[5] = ASSIGN/29.99996
$$<<<机器设计精度>>>，允许误差(u)---------------------------------------------
TOLERROR = ASSIGN/1.2
$$----------------------------------------------------------
GAGEHEIGHT = ASSIGN/37
GAGEWIDTH = ASSIGN/9
ENDCLEAR = ASSIGN/2.5
ANS = PROMPT/'START CNC MEASUREMENT [ Y/N ] '
IF/(ANS .EQ. 'Y') .OR. (ANS .EQ. 'Y')
PRCOMP/OFF
JUMPTO/(CNCSTART)
ENDIF
RECALL/D(MCS)
UNITS/MM,ANGDEC
PRCOMP/OFF
MODE/MAN
F(PTL1)=FEAT/POINT,CART,1 ,0, 0, 0, 0, 1
F(PTL2)=FEAT/POINT,CART,2 ,0, 0, 0, 0, 1
F(PTL3)=FEAT/POINT,CART,3 ,0, 0, 0, 0, 1
F(PTL4)=FEAT/POINT,CART,4 ,0, 0, 0, 0, 1
F(PTL5)=FEAT/POINT,CART,5 ,0, 0, 0, 0, 1
F(PTL6)=FEAT/POINT,CART,6 ,0, 0, 0, 0, 1
MEAS/POINT,F(PTL1),1
ENDMES
MEAS/POINT,F(PTL2),1
ENDMES
MEAS/POINT,F(PTL3),1
ENDMES
MEAS/POINT,F(PTL4),1
ENDMES
MEAS/POINT,F(PTL5),1
ENDMES
MEAS/POINT,F(PTL6),1
ENDMES
(CNCSTART)
MODE/PROG,MAN
VI = OBTAIN/FA(PTL1)[1],5
VJ = OBTAIN/FA(PTL1)[1],6
VK = OBTAIN/FA(PTL1)[1],7
F(BFPL1) = FEAT/PLANE,CART, 0.0, 0.0, 0.0, VI, VJ, VK
VI = OBTAIN/FA(PTL5)[1],5
VJ = OBTAIN/FA(PTL5)[1],6
VK = OBTAIN/FA(PTL5)[1],7
VI2 = OBTAIN/FA(PTL4)[1],5
VJ2 = OBTAIN/FA(PTL4)[1],6
VK2 = OBTAIN/FA(PTL4)[1],7
F(BFLN1) = FEAT/LINE,BND,CART, 0, 0, 0, -VI2, -VJ2, -VK2, VI, VJ, VK
CONST/PLANE,F(BFPL1),BF,FA(PTL1),FA(PTL2),FA(PTL3)
CONST/LINE,F(BFLN1),BF,FA(PTL5),FA(PTL6)
D(GAGG1CRD) = DATSET/FA(BFPL1), ZDIR, ZORIG, FA(BFLN1), -XDIR, YORIG, FA(PTL4), XORIG
PROB = VALUE/SNSLCT
DR_PRBRAD = OBTAIN/SS(PROB), 8
DR_PRBRAD = ASSIGN/(DR_PRBRAD/2)
D(GAGG1CRD) = TRANS/ZORIG, -DR_PRBRAD, YORIG, -DR_PRBRAD, XORIG, -DR_PRBRAD
DID(GageBlock) = DEVICE/STOR,'GagaBlockResult.out'
OPEN/DID(GageBlock), DIRECT, OUTPUT, APPEND
DID(DEFAULTSCREEN) = DEVICE/TERM,'SCREENOUTPUT'
OPEN/DID(DEFAULTSCREEN),FDATA,V(DEFAULTFORMAT),OUTPUT
M(GAGECRDSETUP) = MACRO/'CRDLABEL', ADVX, ADVZ, GHEIGHT, GWIDTH, GLENGTH, GCLEAR, PRBR
RECALL/D(GAGG1CRD)
D() = TRANS/ZORIG, ADVZ, XORIG, ADVX
GOTO/-10, HEIGHT, 5
F(ZPLANE) = FEAT/PLANE,CART, 0.0, 0.0, 0.0, 0, 0, 1
F(XLINE) = FEAT/LINE,BND,CART, 0, 0, 0, 1, 0, 0, 0, 1, 0
F(XORIG)=FEAT/POINT,CART,6 ,0, 0, 1, 0, 0
MEAS/PLANE,F(ZPLANE), 3
PTMEAS/CART, -GCLEAR, -(GHEIGHT/10), 0, 0, 0, 1
PTMEAS/CART, -GCLEAR, -(GHEIGHT*2/10), 0, 0, 0, 1
GOTO/-3, HEIGHT, 5
GOTO/-(GLENGTH-3), HEIGHT, 5
PTMEAS/CART, -(GLENGTH-ENDCLEAR), -(GHEIGHT/6), 0, 0, 0, 1
ENDMES
MEAS/LINE,F(XLINE), 2
GOTO/-GLENGTH,HEIGHT, 5
PTMEAS/CART, -(GLENGTH-GCLEAR), 0, -(GWIDTH/2), 0, 1, 0
GOTO/-(GLENGTH-3), HEIGHT, -(GWIDTH/2)
GOTO/-5, HEIGHT, -(GWIDTH/2)
PTMEAS/CART, -GCLEAR, 0, -(GWIDTH/2), 0, 1, 0
ENDMES
GOTO/0, HEIGHT, -(GWIDTH/2)
MEAS/POINT,F(XORIG), 1
PTMEAS/CART, 0, -(GHEIGHT/8), -(GWIDTH/2), 1, 0, 0
ENDMES
GOTO/0, HEIGHT, -(GWIDTH/2)
$$(ANS .EQ. 'N') .AND.
IF/(BL .EQ. BLENGTH[1])
RECALL/D(MCS)
DX = OBTAIN/FA(XORIG),6
DY = OBTAIN/FA(XORIG),7
DZ = OBTAIN/FA(XORIG),8
DCX = ASSIGN/ABS(DX)
DCY = ASSIGN/ABS(DY)
DCZ = ASSIGN/ABS(DZ)
BARDIR = ASSIGN/MX(DCX,DCY,DCZ)
BARAXIS = ASSIGN/'非 常规角'
IF/(BARDIR .GT. 0.95)
IF/(DCX .GT. 0.95)
BARAXIS = ASSIGN/'X轴'
ENDIF
IF/(DCY .GT. 0.95)
BARAXIS = ASSIGN/'Y轴'
ENDIF
IF/(DCZ .GT. 0.95)
BARAXIS = ASSIGN/'Z轴'
ENDIF
ELSE
IF/(BARDIR .LT. 0.72) .AND. (BARDIR .GT. 0.69)
IF/(DCX.LE.0.1)
IF/(DY.LT.0)
BARAXIS = ASSIGN/'YZ直角__OB'
ELSE
BARAXIS = ASSIGN/'YZ直角__AC'
ENDIF
ENDIF
IF/(DCY.LE.0.1)
IF/(DX.LT.0)
BARAXIS = ASSIGN/'ZX直角__OB'
ELSE
BARAXIS = ASSIGN/'ZX直角__AC'
ENDIF
ENDIF
IF/(DCZ.LE.0.01)
IF/((DX + DY) .LT. 0.05)
BARAXIS = ASSIGN/'XY直角__AC'
ENDIF
IF/((DX + DY) .GT. 1.4) .OR. ((DX + DY) .LT. -1.4)
BARAXIS = ASSIGN/'XY直角__OB'
ENDIF
ENDIF
IF/(DCX .LT. 0.53) .AND. (DCX .GT. 0.47) .AND. (DCY .LT. 0.53) .AND. (DCY .GT. 0.47)
IF/(DX .LT. 0) .AND. (DY .LT. 0)
BARAXIS = ASSIGN/'空间1'
ENDIF
IF/(DX .GT. 0) .AND. (DY .LT. 0)
BARAXIS = ASSIGN/'空间2'
ENDIF
IF/(DX .GT. 0) .AND. (DY .GT. 0)
BARAXIS = ASSIGN/'空间3'
ENDIF
IF/(DX .LT. 0) .AND. (DY .GT. 0)
BARAXIS = ASSIGN/'空间4'
ENDIF
ENDIF
ENDIF
ENDIF
WRITE/DID(DEFAULTSCREEN),' '
WRITE/DID(DEFAULTSCREEN),' 量块方向：',BARAXIS
ENDIF
D() = DATSET/FA(ZPLANE), ZDIR, ZORIG, FA(XLINE), XDIR, YORIG, FA(XORIG), XORIG
D() = TRANS/ZORIG, -PRBR, YORIG, -PRBR, XORIG, -PRBR
ENDMAC
M(GAGECHECK) = MACRO/GHEIGHT, GWIDTH, GLENGTH, PRBR
DECL/LOCAL, REAL, XS, XE, ACTLENGTH,ERROR1,ERROR2,ERROR3,ERROR4,TOL1,MAXERROR,MINERROR,MAXIMUM,MINIMUM,JJYYCHANGE,AVERAG,AVERAG1
DECL/LOCAL, CHAR, 20, SSEP,SSEP1,SSEP2,SSEP3,STESTDATE, STESTTIME,JJYY,NY
DECL/LOCAL, INTGR, LPCOUNT,LPCOUNT1
DECL/LOCAL,DOUBLE,JJYY[LPNUM]
ERROR3 = ASSIGN/LPNUM
$$ SSEP = ASSIGN/'--------------------------------------------------------------------------------'
$$ WRITE/DID(GageBlock), SSEP
$$ WRITE/DID(DEFAULTSCREEN),SSEP
F(PTS)=FEAT/POINT,CART,0 ,0, 0, 1, 0, 0
F(PTE)=FEAT/POINT,CART,-GLENGTH ,0, 0, -1, 0, 0
STD = ASSIGN/0
SELECT/BL
CASE/BLENGTH[1]
TOL1 = ASSIGN/(TOLERROR+BLENGTH[1]/500)/1000
ENDCAS
CASE/BLENGTH[2]
TOL1 = ASSIGN/(TOLERROR+BLENGTH[2]/500)/1000
ENDCAS
CASE/BLENGTH[3]
TOL1 = ASSIGN/(TOLERROR+BLENGTH[3]/500)/1000
ENDCAS
CASE/BLENGTH[4]
TOL1 = ASSIGN/(TOLERROR+BLENGTH[4]/500)/1000
ENDCAS
CASE/BLENGTH[5]
TOL1 = ASSIGN/(TOLERROR+BLENGTH[5]/500)/1000
ENDCAS
ENDSEL
DO/LPCOUNT, 1,LPNUM
GOTO/5, HEIGHT, -(GWIDTH/2)
MEAS/POINT,F(PTS), 1
PTMEAS/CART, 0, -(GHEIGHT/4), -(GWIDTH/2), 1, 0, 0
ENDMES
GOTO/5, HEIGHT, -(GWIDTH/2)
GOTO/-GLENGTH-8, HEIGHT, -(GWIDTH/2)
MEAS/POINT,F(PTE), 1
PTMEAS/CART, -GLENGTH, -(GHEIGHT/4), -(GWIDTH/2), -1, 0, 0
ENDMES
XS = OBTAIN/FA(PTS), 3
XE = OBTAIN/FA(PTE), 3
$$ WRITE/DID(DEFAULTSCREEN),''
$$ STESTDATE = ASSIGN/SDATE()
$$ STESTTIME = ASSIGN/STIME()
$$ WRITE/DID(GageBlock), 'DATE : ', STESTDATE, ' TIME : ', STESTTIME
$$ WRITE/DID(DEFAULTSCREEN),'DATE : ', STESTDATE, ' TIME : ', STESTTIME
ACTLENGTH = ASSIGN/(XS - XE) - (2.0 * PRBR)
ERROR1 = ASSIGN/ACTLENGTH-GLENGTH
$$ WRITE/DID(GageBlock), 'RUN ', LPCOUNT, 'Actual Length = ', ACTLENGTH, ' Nominal Length : ', GLENGTH ,$
$$ ' ERROR:',ERROR1,' TOL: ',TOL1
ERROR4 = ASSIGN/ABS(ERROR1)
IF/(ERROR4.GT.TOL1)
NY = ASSIGN/'NG'
ELSE
NY = ASSIGN/'OK'
ENDIF
TOL1 = ASSIGN/TOL1*1000
ERROR1 = ASSIGN/ERROR1*1000
IF/(LPCOUNT.EQ.1)
MINERROR = ASSIGN/ERROR1
MAXERROR = ASSIGN/ERROR1
AVERAG = ASSIGN/ERROR1/1000
WRITE/DID(DEFAULTSCREEN),''
WRITE/DID(DEFAULTSCREEN),' ','序号 ',' ','理论值',' ','实测值 ',' ','示值误差(u)',' ','允许误差(u)',' ','测试结论'
ENDIF
IF/(ERROR1.LT.0)
SSEP2 = ASSIGN/' '
ELSE
SSEP2 = ASSIGN/' '
ENDIF
SSEP1 = ASSIGN/' '
IF/(GLENGTH.EQ.50)
SSEP1 = ASSIGN/' '
IF/(ERROR1.LT.0)
SSEP2 = ASSIGN/' '
$$*/
ELSE
SSEP2 = ASSIGN/' '
ENDIF
ENDIF
SSEP3 = ASSIGN/' '
WRITE/DID(DEFAULTSCREEN),' ',LPCOUNT:2:2,' ',GLENGTH:5:5,SSEP1,ACTLENGTH:5:5,SSEP2,ERROR1:2:2,SSEP3,TOL1:2:2,SSEP3,NY
$$ WRITE/DID(DEFAULTSCREEN),'RUN ', LPCOUNT, 'Actual Length = ', ACTLENGTH, ' Nominal Length : ', GLENGTH , $
$$ ' ERROR:',ERROR1,' TOL: ','-/+',TOL1
TOL1 = ASSIGN/TOL1/1000
IF/(ERROR1 .LT. MINERROR)
MINERROR = ASSIGN/ERROR1
ENDIF
IF/(ERROR1 .GT. MAXERROR)
MAXERROR = ASSIGN/ERROR1
ENDIF
JJYY[LPCOUNT] = ASSIGN/ERROR1
KNPTR1 = ASSIGN/MINERROR
KNPTR2 = ASSIGN/MAXERROR
IF/(LPCOUNT.GT.1)
AVERAG = ASSIGN/ERROR1/1000 + AVERAG
ENDIF
KNPTR3 = ASSIGN/KNPTR2-KNPTR1
$$ JJYY[LPCOUNT] = ASSIGN/ABS(JJYY[LPCOUNT])
$$ STD = ASSIGN/0
$$ ERROR1 = ASSIGN/ABS(ERROR1)
$$ IF/(ERROR1.GT.STD)
$$ STD = ASSIGN/ERROR1
$$ ENDIF
GOTO/-GLENGTH, HEIGHT, -(GWIDTH/2)
GOTO/0, HEIGHT, -(GWIDTH/2)
ENDDO
$$ WRITE/DID(DEFAULTSCREEN),'MAXMUM ERROR IS ',STD
IF/(MAXERROR+MINERROR.GT.0)
MAXIMUM = ASSIGN/MAXERROR
$$ MINIMUM = ASSIGN/MINERROR
ELSE
$$ MAXIMUM = ASSIGN/MINERROR
MINIMUM = ASSIGN/MAXERROR
ENDIF
AVERAG = ASSIGN/AVERAG/LPNUM+GLENGTH
$$ WRITE/DID(DEFAULTSCREEN),'MAXMUM ERROR IS ',KNPTR2:5:5,' MINIMUM ERROR IS ',KNPTR1:5:5
$$ WRITE/DID(DEFAULTSCREEN),' REPEATABILITY ERROR ',KNPTR3:5:5
WRITE/DID(DEFAULTSCREEN),' ','实测平均值: ', AVERAG:5:5
WRITE/DID(DEFAULTSCREEN),' ','重复性误差: ', KNPTR3:2:2
ENDMAC
$$DECL/COMMON,INTGR,II
$$DO/II,1,5
ZP = ASSIGN/ZGAP[1]
XP = ASSIGN/XGAP[1]
BL = ASSIGN/BLENGTH[1]
CALL/M(GAGECRDSETUP), (GAGE1CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
ZP = ASSIGN/ZGAP[2]
XP = ASSIGN/-XGAP[2]
BL = ASSIGN/BLENGTH[2]
CALL/M(GAGECRDSETUP), (GAGE2CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
ZP = ASSIGN/ZGAP[3]
XP = ASSIGN/-XGAP[3]
BL = ASSIGN/BLENGTH[3]
CALL/M(GAGECRDSETUP), (GAGE3CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
ZP = ASSIGN/ZGAP[4]
XP = ASSIGN/-XGAP[4]
BL = ASSIGN/BLENGTH[4]
CALL/M(GAGECRDSETUP), (GAGE4CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
ZP = ASSIGN/ZGAP[5]
XP = ASSIGN/-XGAP[5]
BL = ASSIGN/BLENGTH[5]
CALL/M(GAGECRDSETUP), (GAGE5CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
$$ENDDO
MODE/MAN
CLOSE/DID(GageBlock)
$$ENDFIL
